The procedure VAL does what you want. It is used by the system when
you type in a hex string.

const
 s:string='1234ABCD';
var
  l:longint;
  errpos:integer;
begin
  val('$'+s,l,errpos);
  if errpos>0 then writeln('SHIT');
  writeln(l)
end.

Val('$'+s,x,err);

-Subject: Converting the number base

42. *****
 Q: How do I convert a decimal word into a hexadecimal string, etc?

 A: Here is one possibility
  function HEXFN (decimal : word) : string;
  const hexDigit : array [0..15] of char = '0123456789ABCDEF';
  begin
    hexfn := hexDigit[(decimal shr 12)]
          + hexDigit[(decimal shr 8) and $0F]
          + hexDigit[(decimal shr 4) and $0F]
          + hexDigit[(decimal and $0F)];
  end;  (* hexfn *)
Here is another conversion example (from longint to binary string)
  function LBINFN (decimal : longint) : string;
  const BinDigit : array [0..1] of char = '01';
  var i     : byte;
      binar : string;
  begin
    FillChar (binar, SizeOf(binar), ' ');
    binar[0] := chr(32);
    for i := 0 to 31 do
      binar[32-i] := BinDigit[(decimal shr i) and 1];
    lbinfn := binar;
  end;  (* lbinfn *)
For a full set of conversions, both from and to decimal, apply
TSUTNTB.TPU from ftp://garbo.uwasa.fi/pc/ts/tspa3570.zip.

 A2: In the case of converting a hexadecimal string into a decimal
number another option can be used, i.e. the Val function:
  (* Convert hexadecimal string to a decimal value *)
  function HEX2DEC (hex: string) : longint;
  var dec : longint;
      k   : integer;
  begin
    Val ('$'+hex, dec, k);
    if k = 0 then
      if dec < 0 then begin
        writeln (hex, ' out of range (longint becomes negative)');
        halt(1);
        end
      else hex2dec := dec
    else begin
      writeln (hex, ' error or out of range');
      halt(1);
      end;
  end;
--------------------------------------------------------------------

   All the best, Timo

....................................................................
Prof. Timo Salmi   Co-moderator of news:comp.archives.msdos.announce
Moderating at ftp:// & http://garbo.uwasa.fi/ archives 193.166.120.5
Department of Accounting and Business Finance  ; University of Vaasa
mailto:t...@uwasa.fi <http://www.uwasa.fi/~ts/>  ; FIN-65101,  Finland

How about (untested, but very like part of my pas-opts.htm; over-short
names)

function LB(D : longint) : string ;
const BD : array [boolean] of char = '01' ;
var j : byte ; S : string ;
begin {omit FillChar}
  S[0] := #32 ;
  for j := 32 downto 1 do begin
    S[j] := BD[Odd(D)] ; D := D shr 1 end ;
  LB := S end ;

?

Personally I'd go for:

  function LB(d : longint) : String;
  const BD : array[boolean] of char = '01';
  var j : byte; S: string;
  begin
       S[0] := #32;
       for j := 0 to 31 do
       S[32-j] := BD[d and (1 shl j) <> 0];
       LB := s;
  end;

Although no byte saving on Timo's version without FillChar, it does
execute around 35-40% faster than the two versions above.

--
Pedt

True, but I prefer to put it there routinely, especially in the FAQ.

:  function LB(d : longint) : String;
:  const BD : array[boolean] of char = '01';
:  var j : byte; S: string;
:  begin
:       S[0] := #32;
:       for j := 0 to 31 do
:       S[32-j] := BD[d and (1 shl j) <> 0];
:       LB := s;
:  end;
:
:Although no byte saving on Timo's version without FillChar, it does
:execute around 35-40% faster than the two versions above.

I'll include this as a joint alternative from John and you.

   All the best, Timo

....................................................................
Prof. Timo Salmi   Co-moderator of news:comp.archives.msdos.announce
Moderating at ftp:// & http://garbo.uwasa.fi/ archives 193.166.120.5
Department of Accounting and Business Finance  ; University of Vaasa
mailto:t...@uwasa.fi <http://www.uwasa.fi/~ts/>  ; FIN-65101,  Finland