Hello All.

Is the anybody here knows how to append EXE file
to the another EXE file, and they both will works,
please answer me. I'll be very glad to get a simple of this.

function flength (var name : pathstr) : longint;

var
  s : searchrec;

begin
  findfirst (name,anyfile,s);
  if DOSError=0 then
    flength := s.size
  else
    flength := -1;
end;

function EXElength (var name : pathstr) : longint;

type
  EXEheader = record
    ID : word;
    bytemod : word;
    pages : word;
    relocitems : word;
    size : word;
    minparagraphs : word;
    maxparagraphs : word;
    stackseg : word;
    SPreg : word;
    checksum : integer;
    IPreg : word;
    codeseg: word;
    firstreloc: word;
    ovlnum: word;
  end;

var
  f : file of EXEheader;
  header : EXEheader;

begin
  assign (f,name);
  reset (f);
  read (f,header);
  close (f);
  with header do
    EXElength := longint(bytemod)+(longint(pred(pages))*512);
end;

function appendedfile (var name : pathstr) : boolean;

begin
  appendedfile := EXElength(name)<>flength(name);
end;

Copying and calling the second .EXE could be a possibility, but is probably
sloppier than just having a separate program in the first place.  I have never
really understood the rationale for wanting to paste two EXEs together like
this in the first place.

One point that hasn't been mentioned yet is that most of the
garbage appended to the end of the exe uses a signature-type
record defined in the object unit as --
 THeader = record
   Signature: Word;
   case Integer of
     0: (
       LastCount: Word;
       PageCount: Word;
       ReloCount: Word);
     1: (
       InfoType: Word;
       InfoSize: Longint);
 end;

This record prefixes components such as debug information,
overlays, resource files, help files, etc.  Using this record on
the exe, you'll find the exe's "MZ" signature is $5A4D and that
subsequent "FB" signatures are $4246.  To locate a section you set
the position to 0 and walk the exe looking for the appropriate
InfoType.

The TVision resource file defines:
  RStreamMagic   : Longint = $52504246; { 'FBPR' }
  RStreamBackLink: Longint = $4C424246; { 'FBBL' }

TVision helpfile defines:
  HelpFileMagic  = $46484246;           { 'FBHF' }

For example, the following was removed from tStream.Init to allow
searching a DOS real mode exe for any specified resource. The new
method allows appending a TVision help file as well as a resource
file or user define block. (note that BasePos must be initialized
before calling).  Of course there are other pieces missing.  But
if you have the RTL you have everything you need.

Function tStream.AlignResource
  (VAR BasePos: Longint; Magic: Longint): Boolean;

VAR Found, Stop: Boolean;
    Header     : THeader;
BEGIN
    Found := False;
    REPEAT
       Stop := True;
       If BasePos <= GetSize - SizeOf(THeader) Then
       Begin
          Seek(BasePos);
          Read(Header, SizeOf(THeader));
          Case Header.Signature of
             $5A4D:
             Begin
                Inc(BasePos, LongMul(Header.PageCount, 512) -
                   (-Header.LastCount and 511));
                 Stop := False;
             End;
             $4246:
                If  (Header.InfoType = LongRec(Magic).Hi)
                and (LongRec(Magic).Lo = $4246)
                Then
                    Found := True
                Else Begin
                    Inc(BasePos, Header.InfoSize + 8);
                    Stop := False;
                End;
          End{Case};
       End;
    UNTIL Stop;
    AlignResource := Found;
End;

    ...red