Listen to my tunes!
http://www.mp3.com/rawlyn

program BINARY_TREE;      { Binary Tree with Pointers Example }
const EOD = -98765;                       { End-of-Data value }
type BTT  = ^NODE;                      { define pointer type }
     NODE = record                   { template for tree node }
       NUM    : integer;                         { node value }
       LP, RP : BTT                                { pointers }
     end;
var  CURR : integer;                    { current input value }
     TREE : BTT;                           { pointer variable }
     MORE : boolean;                     { input data control }
procedure INSERT (var WORK : BTT);{ insert value(s) into tree }
                             { This procedure is Recursive... }
var  NEWP : BTT;                      { local working pointer }
begin
  if WORK = Nil then
    begin                          { insert element into tree }
      New (NEWP);               { obtain new pointer location }
      with NEWP^ do
        begin
          NUM := CURR;                { add value to new node }
          LP  := Nil;        { set new node pointers to "Nil" }
          RP  := Nil; RP  := Nil
        end;
      WORK := NEWP                { move local node into tree }
    end
  else   if CURR < WORK^.NUM then      { belongs on left side }
           INSERT (WORK^.LP)              { walk left node(s) }
         else                         { belongs on right side }
           INSERT (WORK^.RP)             { walk right node(s) }
end;                                           { of procedure }
procedure PRINTTREE (FILLED : BTT);         { print tree data }
begin
  if FILLED <> nil then                   { process some data }
    begin
      PRINTTREE (FILLED^.LP);          { process left node(s) }
      write (FILLED^.NUM:5);   { write out current node value }
      PRINTTREE (FILLED^.RP)          { process right node(s) }
    end
end;                                           { of procedure }
begin                                             { Main Line }
  MORE := true; TREE := Nil;                     { initialize }
  writeln ('Enter random integers; terminate with -98765');
  while MORE do
    begin                             { read data & load tree }
      read (CURR);                        { read a data value }
      if CURR = EOD then MORE := false          { end of data }
      else INSERT (TREE)                       { process data }
    end;                                           { of while }
  writeln ('Sorted input numbers:');                { heading }
  PRINTTREE (TREE);                  { walk & print tree data }
  writeln; writeln ('Finis...')
end.

Heinrich

Heinrich

--
This posting was manufactured to meet critical quality standards.
If you believe the posting has a manufacturing defect, please call our
Quality Management Department at ++49-800-BASTISOFT.